<ИмяКалендаря>

Установить значение календаря конкретного вида.

Синтаксис:

<ИмяКалендаря>

Описание:

Атрибут <ИмяКалендаря> задает значение календаря конкретного вида. В тексте программного модуля используется название конкретного вида календа­ря, как он назван в конфигураторе.

Пример:

Календари.Служащие.Дней(ТекДата, ТекДата + 5);

ИмяКомпьютера

Получить сетевое имя компьютера.

Синтаксис:

ИмяКомпьютера()

Англоязычный синоним:

ComputerName

Возвращаемое значение:

Строковое значение — сетевое имя компьютера, работающего в данный мо­мент с программой.

Описание:

Функция ИмяКомпьютера возвращает сетевое имя компьютера, работающе­го в данный момент с программой.

Пример:

Компьютер = ИмяКомпьютера();

<ИмяОбласти>

Возвращает или задает значение, записанное в именованной области таблицы в режиме ввода данных.

Синтаксис:

<ИмяОбласти>

Имя области таблицы, как она задана в табличном документе.

Описание:

Атрибут <ИмяОбласти> позволяет обращаться к значениям, записанным в поименованных областях таблицы в режиме ввода данных. Для обращения к значению конкретной области следует указать имя этой области, заданный в конфигураторе.

Данный атрибут существует и доступен в форме, если при конфигурирова­нии данной формы в свойствах формы выбраны опция «Использовать табли­цу» — «Для ввода данных». Установка данной опции в свойствах формы означа­ет наличие у данной формы таблицы в режиме ввода данных. В процессе кон­фигурирования в таблице можно задать любое число выделенных и поимено­ванных областей.

Доступ к данному атрибуту возможен только в контексте Модуля формы отчета или обработки.

Замечание: Данный атрибут работает на чтение только в том случае, если в качестве области таблицы помечена одна единственная ячейка.

Пример:

* В диалоге формы есть элемент диалога ВыбКод. В форме использована таблица в режиме ввода данных. Одна из ячеек таблицы помечена как об­ласть с именем «ВыбранныйКлиент». В этом случае в модуле формы мож­но задать значение данной области.

Клн = СоздатьОбъект("Справочник.Клиенты");

Клн.НайтиПоКоду(ВыбКод, 0);

ВыбранныйКлиент = Клн.ТекущийЭлемент();

См. также: разд. «Работа с таблицами»

<ИмяОбласти>

Возвращает или задает объект «область».

Синтаксис:

<ИмяОбласти>

Идентификатор области секции, как она задана в конфигураторе.

Описание:

В процессе конфигурирования для секции можно задавать практически не­ограниченное число дополнительно выделенных и поименованных областей для выделения любой необходимой информации.

Атрибут <ИмяОбласти> позволяет обращаться к поименованной области секции. Для обращения к конкретной области секции следует указать ее иден­тификатор, заданный для этой области в конфигураторе.

Пример:

Таб = СоздатьОбъект("Таблица");

Таб.Открыть("tabl_l.mxl");

Секция = Таб.ПолучитьСекцию("ЗаголовокОтчета");

Секция.Заглавие.Текст = "Товарный отчет";

Таб.ВывестиСекцию(Секция);

<ИмяОбласти>

Предоставляет доступ к именованной области таблицы в режиме ввода данных.

Синтаксис:

<ИмяОбласти>

Имя области таблицы в режиме ввода данных.

Описание:

В процессе конфигурирования для таблицы в режиме ввода данных можно задавать практически неограниченное число поименованных областей.

Атрибут <имяОбласти> позволяет обращаться к поименованной области таблицы. Для обращения к конкретной области следует указать ее имя, задан­ное для этой области в конфигураторе.

Пример:

Таблица.Заглавие.Текст = "Товарный отчет";

ИмяПользователя

Получить имя пользователя.

Синтаксис:

ИмяПользователя()

Англоязычный синоним:

UserName

Возвращаемое значение:

Строковое значение — имя пользователя, работающего в данный момент с программой.

Описание:

Функция ИмяПользователя возвращает имя пользователя (указанное в конфигураторе в списке пользователей), работающего в данный момент с про­граммой.

Пример:

Спр = СоздатьОбъект("Справочник.Сотрудники");

Спр.НайтиПоКоду(ИмяПользователя());

Менеджер = Спр.ТекущийЭлемент();

Если Менеджер.Выбран() = 0 Тогда

   Предупреждение("Не выбран менеджер!");

КонецЕсли;

Индексный файл

Индексы хранятся в индексном файле. Индексный файл может содержать информацию более чем об одном индексе.

Индексы, выражения индекса и фильтра

Для организации упорядочивания содержимого файла БД и поиска в ней по значению одного или нескольких полей применяется механизм индексов. Его применение можно сравнить с сортировкой картотеки по определенному при­знаку (совокупности признаков). Однако, в отличие от картотеки, файл БД может иметь сразу несколько индексов, и, соответственно, являться упорядо­ченным одновременно по нескольким признакам. Каждый индекс имеет наиме­нование, признак уникальности, выражение

индекса и фильтр. Наименование индекса используется для идентификации индекса. Выражение индекса и фильтр представляют собой написанные на специальном языке выражения, вычисление значения которых для каждой записи позволяет определить ее ме­сто при упорядочивании и необходимость помещения ее в упорядоченный спи­сок (индекс может содержать упоминание не обо всех записях таблицы, а толь­ко об удовлетворяющих выражению фильтра). Подробнее выражения индекса и фильтра, применительно к объектам XBase, рассмотрены в конце данного раздела. Уникальный индекс (имеющий установленным признак уникально­сти) позволяет иметь в индексе ссылки на записи только с различным значени­ем индексного выражения.

Initialize

Выполнить инициализацию системы 1С:Предприятие.

Синтаксис:

Initialize(<Имя_Объекта>.RMTrade, <КоманднаяСтрока>, <ПустаяСтрока>)

Англоязычный синоним:

Initialize

Параметры:

<Имя_Объекта>	Идентификатор созданного OLE объекта 1С:Предприятие.
RMTrade	Добавочное ключевое слово.
<КоманднаяСтрока>	Строковое выражение — командная строка за­пуска 1С:Предприятие.
<ПустаяСтрока>	Строковое выражение. Параметр может содер­жать пустую строку или строковое значение "NO_SPLASH_SHOW" — отключить заставку при запуске системы 1С:Предприятие в режиме OLE Automation сервера.

Возвращаемое значение:

Значение логического типа: TRUE, если инициализация прошла удачно, или FALSE, если нет.

Замечание: В OLE Automation TRUE и FALSE имеют соответственно значе­ния: -1 (минус единица) и 0.

Описание:

Метод Initialize выполняет инициализацию системы 1С:Предприятие.

Пример:

* здесь пример приводится на языке MS Visual Basic:

Dim v7 As Object

Set v7 = CreateObject("V77.Application")

result = v7.Initialize(v7.RMTrade, "/DC:\V7\DB /M", "")

ИсходнаяТаблица

Переназначить исходную таблицу.

Синтаксис:

ИсходнаяТаблица(<Строка>)

Англоязычный синоним:

SourceTable

Параметры:

<Строка>

Строковое выражение, содержащее имя исходной таблицы формы, определенное в конфигураторе, или имя файла, содержащего таблицу.

Описание:

Метод ИсходнаяТаблица переназначает в качестве исходной таблицы-шаблона одну из таблиц той формы, в программном модуле которой запущена данная процедура. Имя таблицы сначала ищется в форме модуля, потом в об­щих таблицах. Если такой таблицы нет, то переданное имя будет рассматри­ваться как имя файла, содержащего данную таблицу.

Пример:

Таб = СоздатьОбъект("Таблица");

Таб.ИсходнаяТаблица("price");

Таб.Вывести();

Таб.ТолькоПросмотр(0);

Таб.Показать("Каталог", "Catalog.mxl");

Таб.ТолькоПросмотр(1);

ИспользоватьДату

Установить дату выборки периодических реквизитов справочника.

Синтаксис:

ИспользоватьДату[<Дата>, <УстСразу>)

Англоязычный синоним:

UseDate

Параметры:

<Дата>

Необязательный параметр. Выражение со значением типа «дата».

<УстСразу>

Необязательный параметр. Число: если 1, то дата, пере­данная в качестве параметра, будет установлена уже в те­кущей выборке; если 0 — то дата, переданная в качестве параметра будет установлена при следующей выборке. Значение по умолчанию — 0. Например: если "Цена" — периодический реквизит справочника, то Спр.ИспользоватьДату(Д1, 1); Спр.ВыбратьЭлементы(); А = Спр.Цена; — возвращает значение на дату Д1 Спр.ИспользоватьДату(Д2, 1); Б = Спр.Цена; — возвращает значение на дату Д2! Если <УстСразу> — 0 (или опущен), то Спр.ИспользоватьДату(Д1); Спр.ВыбратьЭлементы(); А = Спр.Цена; — возвращает значение на дату Д1 Спр.ИспользоватьДату(Д2); Б=Спр.Цена; — тоже возвращает значение на дату Д1! Спр.ВыбратьЭлементы(); В=Спр.Цена; — только теперь возвращает значение на Д2.

Возвращаемое значение:

Текущее значение используемой даты (на момент до исполнения метода).

Описание:

Метод ИспользоватьДату устанавливает для объекта типа «справочник» дату, на которую будут в дальнейшем выбираться (или записываться) значения периодических реквизитов справочника.

Это очень важный метод, о котором необходимо всегда помнить при работе со справочниками, имеющими периодические реквизиты. Если он пропущен, то чначения выбранных периодических реквизитов справочника будут не опреде­лены.

Замечание: Если к объекту типа «справочник» однажды применен метод ИспользоватьДату, то в дальнейшем, чтобы выбирать значения перио­дических реквизитов справочника, нельзя применять к этому же объекту методы Получить и Установить, т. е. в такой последовательности эти методы несовместимы.

Замечание: Данный метод имеет следующую особенность применения: его нельзя использовать «через две точки». Например, если в документе с именем "ДокНакл" есть реквизит "Фирма" типа «справочник», у которо­го есть периодические реквизиты НДС и СН, то следующий оператор:

ДокНакл.Фирма.ИспользоватьДату(Дата);

работать не будет. В данном случае следует просто использовать проме­жуточную переменную, например:

ФирДок = ДокНакл.Фирма;

ФирДок.ИспользоватьДату(РабочаяДата());

НДСДок = ФирДок.НДС;

Пример:

// Здесь мы работаем в локальном контексте модуля Формы

// редактирования документа.

// Реквизит "Должность" в документе является справочником,

// у которого "МинОкл" - периодический реквизит

Длж = СоздатьОбъект("Справочник.Должности");

Длж.ИспользоватьДату(ДатаДок);

Длж.НайтиЭлемент(Должность);

Сообщить(Длж.Наименование + " Минимальный оклад" + Строка(Длж.МинОкл));

См. также: Получить, Установить, НайтиЭлемент, ВыбратьЭлементы

ИспользоватьДату

Установить дату, на которую будут записываться периодические рек­визиты элемента справочника, форма которого открыта.

Синтаксис:

ИспользоватьДату(<Дата>, <Обновить>)

Англоязычный синоним:

UseDate

Параметры:

<Дата>	Выражение со значением типа «дата». Дата, на которую будут записываться периодические реквизиты элемента справочника, форма которого открыта.
<Обновить>	Необязательный параметр. Число: 1 — обновить периоди­ческие реквизиты формы на заданную дату; 0 — не обнов­лять периодические реквизиты формы. Значение по умол­чанию — 0;

Возвращаемое значение:

Значение используемой даты (на момент до исполнения метода).

Описание:

Метод ИспользоватьДату устанавливает для элемента справочника дату, на которую будут записываться периодические реквизиты.

Если данный метод опущен, то значения выбранных периодических рекви­зитов справочника будут записываться на текущую рабочую дату.

Замечание. Данный метод доступен только в контексте Модуля формы эле­мента справочника (см. «Виды программных модулей»). Действие данно­го метода относится только к текущему элементу справочника, который доступен в локальном контексте Модуля формы элемента справочника.

Пример:

// Здесь мы работаем в локальном контексте модуля Формы

// элемента справочника.

// в справочнике есть несколько реквизитов,

// которые являются периодическими реквизитами.

// В форме существует элемент диалога ВыбДата типа «Дата»

Если Число(ВыбДата) <> 0 Тогда

   // задано некоторое значение ВыбДата

   ИспользоватьДату(ВыбДата);

КонецЕсли;

ИспользоватьДату

Установить дату выборки периодических реквизитов формы списка справочника.

Синтаксис:

ИспользоватьДату(<Дата>)

Англоязычный синоним:

UseDate

Параметры:

<Дата>

Выражение со значением типа «дата»

Возвращаемое значение:

Значение даты выборки периодических реквизитов формы списка справоч­ника.

Описание:

Метод ИспользоватьДату устанавливает для формы списка справочника дату, на которую будут в дальнейшем выбираться (или записываться) значения периодических реквизитов справочника.

Данный метод доступен только в контексте Модуля формы списка справоч­ника (см. «Виды программных модулей»). Действие данного метода относится только к текущему справочнику, который доступен в локальном контексте Мо­дуля формы списка справочника.

Пример:

ИспользоватьДату(ДатаДок);

ИспользоватьДату

Установить дату выборки периодических реквизитов счета.

Синтаксис:

ИспользоватьДату(<Дата>)

Англоязычный синоним:

UseDate

Параметры:

<Дата>

Необязательный параметр. Выражение типа «да­та».

Возвращаемое значение:

Текущее значение используемой даты (на момент до исполнения метода). Описание:

Метод ИспользоватьДату устанавливает для объекта типа «Счет» дату, на которую будут в дальнейшем выбираться (или записываться) значения перио­дических реквизитов счета.

Данный метод, используется обычно, если нужно обращаться сразу к не-сколькитм периодическим реквизитам спозиционированного объекта. Для оди­ночных обращений рекомендуется использовать методы периодического рекви­зита счета Получить(<Дата>) и Установить(<Дата>, <3начение>) .

Замечание: Если к объекту типа «Счет» однажды применен метод ИспользоватьДату, то в дальнейшем, чтобы выбирать значения перио­дических реквизитов, нельзя применять к этому же объекту методы Получить и Установить, т. е. в такой последовательности эти методы не­совместимы.

Замечание: Метод ИспользоватьДату устанавливает дату выборки для данного объекта. В случае, если обращение к объекту типа счет выполня­ется по длинному пути (например, Клиент.СчетУчета.СтатусУчета) значение типа «Счет» создается динамически и после первого обращения к нему с вызовом метода ИспользоватьДату уничтожается, поэому при повторном обращении для получении значения реквизита данная уста­новка уже действовать не будет.

Замечание: Метод ИспользоватьДату должен быть вызван до позициониро­вания объекта. В этом случае после позиционирования периодические ре­квизиты будут выдаваться на указанную дату.

Пример:

* Выведем список счетов со значением периодического реквизита "СтатусУчета".

Процедура Сформировать()

   Сч = СоздатьОбъект("Счет.Основной");

   Сч.ИспользоватьДату(РабочаяДата());

   Сч.ВыбратьСчета();

   Пока Сч.ПолучитьСчет() = 1 Цикл

      Сообщить("Статус учета " + Сч.Код + " - " + Сч.СтатусУчета);

   КонецЦикла;

КонецПроцедуры

ИспользоватьДату

Установить дату выборки периодических реквизитов формы списка счетов.

Синтаксис:

ИспользоватьДату(<Дата>)

Англоязычный синоним:

UseDate

Параметры:

<Дата>

Выражение со значением типа «дата»

Возвращаемое значение:

Значение даты выборки периодических реквизитов формы списка счетов.

Описание:

Метод ИспользоватьДату устанавливает для формы списка счетов дату, на которую будут в дальнейшем выбираться (или записываться) значения пе­риодических реквизитов справочника.

Данный метод доступен только в контексте Модуля формы списка счетов (см. «Виды программных модулей»). Действие данного метода относится толь­ко к текущему справочнику, который доступен в локальном контексте Модуля формы списка счетов.

Пример:

ИспользоватьДату(РабочаяДата());

ИспользоватьФормат

Устанавливает стандартный формат по умолчанию для вывода всех выражений выводимых секций таблицы.

Синтаксис:

Использоватьформат(<СтрокаФормата>)

Англоязычный синоним:

DefaultFormat

Параметры:

<СтрокаФормата>

Необязательный параметр. Строковое выраже­ние, содержащее форматную строку (см. Формат).

Возвращаемое значение:

Строковое значение, содержащее текущую форматную строку по умолчанию для таблицы (на момент до исполнения метода).

Описание:

Метод Использоватьформат устанавливает стандартный формат по умол­чанию для вывода всех выражений выводимых секций таблицы. В ячейках таб­лицы, при выводе которых требуется формат, отличный от установленного ме­тодом ИспользоватьФормат, должен быть установлен формат явным образом. Форматная строка записывается через символ "#" после выражения, заданного для ячейки. Если выражение, заданное для ячейки просто завершается символом "#", то будет использоваться системный формат по умолчанию.

Пример:

Таб.ИспользоватьФормат("415.2");

ИспользоватьГрафуОтбора

Установить режим использования графы отбора в запросе.

Синтаксис:

ИспользоватьГрафуОтбора(<ГрафаОтбора>)

Англоязычный синоним:

UseSelectionColumn

Параметры:

<ГрафаОтбора>

Строковое выражение — идентификатор графы отбора, как он задан в конфигура­торе. Данный параметр устанавливает ре­жим использования определенной графы отбора. "*" — автоматический выбор графы отбора. Пустая строка — не использовать графу отбора.

Возвращаемое значение:

Строковое значение: идентификатор использованной реально графы отбора, если метод вызывается после выполнения запроса.

Описание:

Метод устанавливает режим использования графы отбора в запросе. Если метод не используется — по умолчанию устанавливается автоматический выбор графы отбора.

Пример:

Запрос = СоздатьОбъект("Запрос");

ТекстЗапроса =

"//{{ЗАПРОС(ОбработкаДок)

|Период с '01.10.96' по '05.10.96';

|ОбрабатыватьДокументы Все;

|Тов = Документ.РасхНакл.Товар;

|Клиент = Документ.РасхНакл.Клиент;

|Группировка Клиент;

|Группировка Тов;

|Группировка Документ;

|"//)}ЗАПРОС

;

// ЕСЛИ ошибка в запросе, то выход из процедуры

Запрос.ИспользоватьГрафуОтбора("Клиент");

Если Запрос.Выполнить(ТекстЗапроса) = 0 Тогда

   Возврат;

КонецЕсли;

ИспользоватьКорСчет

Установить счет для показа списка корреспондирующих счетов.

Синтаксис:

ИспользоватьКорСчет(<Счет>, <Корреспонденция>)

Англоязычный синоним:

UseCorAccount

Параметры:

<Счет>	Выражение со значением счета.
<Корреспонденция>	Число: 1 — дебетовый счет; 0 — кредитовый счет.

Описание:

Метод ИспользоватьКорСчет устанавливает счет для показа списка кор­респондирующих с ним счетов. Корреспондирующие счета задаются с помощью корректных проводок.

Данный метод доступен в контексте Модуля формы списка счетов (см. «Виды программных модулей»). Действие данного метода относится ко всему текущему списку счетов, который доступен в локальном контексте Модуля формы списка счетов.

Пример:

ИспользоватьКорСчет(ВыбСчет, 1);

ИспользоватьКорСчет

Установка корреспондирующего счета используемого по умолчанию.

Синтаксис:

ИспользоватьКорСчет(<Счет>)

Англоязычный синоним:

UseCorAccount

Параметры:

<Счет>

Необязательный параметр. Значение типа «Счет». Если параметр не задан, установка не изменяется.

Возвращаемое значение:

Значение установки используемого по умолчанию корреспондирующего счета на момент до вызова метода.

Описание:

Данный метод устанавливает в форме используемый по умолчанию коррес­пондирующий счет. Он будет автоматически подставляться проводку взамен не указанных пользователем счетов. Эта возможность может быть использована, например, для ввода первоначальных остатков для автоматической простановки счета, корреспондирующего с введенным.

Пример:

Процедура ПриОткрытии()

   ИспользоватьКорСчет(Константа.СчетПервОстатков);

КонецПроцедуры;

ИспользоватьКорСубконто

Задает фильтр по корреспондирующим субконто для функции

ВыбратьОперацииСПроводками.

Синтаксис:

ИспользоватьКорСубконто(<ВидСубконто>, <Субконто>)

Англоязычный синоним:

UseCorSubconto

Параметры:

<ВидСубконто>	Значение типа «ВидСубконто» — отбор проводок будет выполнен только для корреспондирующих субконто указанного вида.
<Субконто>	Значение субконто — отбор проводок будет вы­полнен только для указанного корреспондирую­щего субконто. Кроме того, в качестве значения данного параметра можно передавать «Список значений».

Описание:

Метод ИспользоватьКорСубконто устанавливает фильтр по корреспон­дирующим субконто, который используется при отборе проводок методом ВыбратьОперацииСПроводками.

Метод ИспользоватьКорСубконто может вызываться последовательно несколько раз. В этом случае фильтры, устанавливаемые этой функцией, сум­мируются.

Пример:

Опер = СоздатьОбъект("Операция");

Опер.ИспользоватьСубконто(ВидыСубконто.Организации, ВыбОрг);

Опер.ИспользоватьКорСубконто(ВидыСубконто.Товары, ВыбТовар);

Опер.ВыбратьОперацииСПроводками(ДатаНач, ДатаКон, "60");

Пока Опер.ПолучитьПроводку() = 1 Цикл

   Сообщить("Сумма " + Опер.Сумма);

КонецЦикла;

ИспользоватьКорСубконто

Устанавливает режим получения итогов методом ВыполнитьЗапрос в разрезе корреспондирующих субконто.

Синтаксис:

ИспользоватьКорСубконто(<ВидСубконто>, <Субконто>, <ТипФильтра>, <ПоГруппам>)

Англоязычный синоним:

UseCorSubconto

Параметры:

<ВидСубконто>	Значение типа «Вид Субконто» — расчет временных итогов будет выполнен только для субконто указанного вида.
<Субконто>	Необязательный параметр. Значение субконто, по которому будут отобраны итоги по аналитике. Если параметр не задан — то считается пустым значением субконто.
<ТипФильтра>	Необязательный параметр. Число — тип фильтра по субконто. Может принимать следующие значе­ния: 1 — разворачивать по данному субконто, 2 — отбирать по данному субконто, 3 — не учитывать это субконто вообще. По умолчанию 1.
<ПоГруппам>	Необязательный параметр. Число — группировка итогов по субконто. Параметр <ПоГруппам> имеет смысл, если параметр <ТипФильтра> равен 1, а вид субконто, заданный параметром <ВидСубконто>, имеет тип значения «Справоч­ник». Параметр может принимать значения; 0 — не показывать итоги по группам справочника; 1 — показывать итоги по группам справочника. По умолчанию 0.

Описание:

Метод ИспользоватьКорСубконто устанавливает режим отбора итогов по субконто методом ВыполнитьЗапрос.

Метод ИспользоватьКорСубконто слудет вызывать до вызова метода ВыполнитьЗапрос. После выполнения метода ВыполнитьЗапрос установки метода ИспользоватьКорСубконто сбрасываются и перед слудеющим запро­сом их нужно устанавливать заново.

Метод ИспользоватьКорСубконто может вызываться последовательно несколько раз. В этом случае установки, выполняемые этим методом сумми­руются.

Использование параметра <ТипФильтра> со значением 1 (разворачивать) в сочетании с выбранной группой справочника в параметре <Субконто> по­зволяет получить итоги по всем элементам данной группы.

Данный метод применяется для расчета перекрестных оборотов между объ­ектами аналитического учета.

Пример:

* Данный запрос формирует итоги по корреспонденции субконто Товары и Клиенты.

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Товары, , 1);

БухИтоги.ИспользоватьКорСубконто(ВидыСубконто.Клиенты, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон);

ИспользоватьОбъект

Задать объект применения.

Синтаксис:

ИспользоватьОбъект(<ИмяРеквизита>, <Объект>)

Англоязычный синоним:

UseObject

Параметры:

<ИмяРеквизита>	Строковое выражение, задающее название перио­дического реквизита справочника или название периодической константы, как они названы в конфигураторе.
<Объект>	Необязательный параметр. Значение элемента справочника, для которого задается применение объекта «Периодический». Данный параметр тре­буется задавать только в случае, если <ИмяРеквизита> — периодический реквизит справочника.

Возвращаемое значение:

Число: 1 — если вызов метода закончился успешно, 0 — если нет.

Описание:

Метод ИспользоватьОбъект задает соответствие созданного ранее объекта типа «Периодический» тому периодическому реквизиту справочника или пе­риодической константе, для которой он будет применяться. Если параметр <ИмяРеквизита> не задан (пустая строка), а параметр <Объект> задает элемент справочника, то выборка будет осуществляться по всем периодическим реквизитам справочника.

Пример:

Вал = СоздатьОбъект("Справочник.Валюты");

// Позиционируем созданный справочник Валюты по известному коду

Вал.НайтиПоКоду(1);

Если Вал.Выбран() = 1 Тогда

   Доллар = Вал.ТекущийЭлемент();

Иначе

   Предупреждение{"Не найдена валюта!");

   Возврат;

КонецЕсли;

ПерВал = СоздатьОбъект("Периодический");

ПерВал.ИспользоватьОбъект("Текущ_курс", Доллар);

ПерВал.ОбратныйПорядок(1);

ПерВал.ВыбратьЗначения();

Пока ПерВал.ПолучитьЗначение() = 1 Цикл

   Курс = ПерВал.Значение;

   ДатаКурса = ПерВал.ДатаЗнач;

КонецЦикла;

ИспользоватьПериод

Установить период выборки итогов оборотного регистра.

Синтаксис 1:

ИспользоватьПериод(<Дата>)

Синтаксис 2:

ИспользоватьПериод(<Год>, <Месяц>, <День>)

Синтаксис 3:

ИспользоватьПериод(<Год>, <НомерНедели>)

Синтаксис 4:

ИспользоватьПериод (<Год>, <Месяц>, <НомерДекады>)

Синтаксис 5:

ИспользоватьПериод(<Год>, <Месяц>)

Синтаксис 6:

ИспользоватьПериод(<Год>, <НомерКвартала>)

Синтаксис 7:

ИспользоватьПериод(<Год>)

Англоязычный синоним:

UseРег1od

Параметры:

<Дата>	Выражение типа «дата».
<Год>	Числовое выражение, содержащее номера года.
<Месяц>	Числовое выражение, содержащее номер месяца.
<День>	Числовое выражение, содержащее номер дня месяца.
<НомерДекады>	Числовое выражение, содержащее номер декады ме­сяца.
<НомерКвартала>	Числовое выражение, содержащее номер квартала.

Описание:

Метод ИспользоватьПериод устанавливает период выборки итогов обо­ротного регистра. Различный синтаксис вызова данного метода зависит от заданного в конфигураторе интервала оборотного регистра.

Заданный в конфигураторе Интервал	Используемый синтаксис
День	синтаксис 1 и 2.
Неделя	синтаксис 1 и 3.
Декада	синтаксис 4.
Месяц	синтаксис 5.
Квартал	синтаксис 6.
Год	синтаксис 7.

Данный метод используется до вызова методов оборотных регистров. Даль­нейшая выборка итогов будет происходить по указанному периоду. Если при работе с оборотным регистром этот метод опущен, то по умолчанию использу­ется текущий период, в котором находится ТА.

Пример:

Регистр.ОборотыТоваров.ИспользоватьПериод(1996);

ИспользоватьПланСчетов

Устанавливает план счетов, который будет использован объектом.

Синтаксис:

ИспользоватьПланСчетов(<ПланСчетов>)

Англоязычный синоним:

UseChartOfAccounts

Параметры:

<ПланСчетов>

Значение типа «План Счетов».

Возвращаемое значение:

Значение типа «План Счетов». Текущее значение на момент до исполнения метода.

Описание:

Данный метод выдает и устанавливает для объекта план счетов, который будет использован им в дальнейшем для поиска, выбора, обхода счетов.

Метод ИспользоватьПланСчетов имеет смысл использовать в том случае, если объект создан функцией СоздатьОбъект для работы с разными планами счетов — СоздатьОбъект("Счет"). Если объект был создан для работы с конкретным планом счетов, то все операции поиска и обхода счетов будут ра­ботать только с этим планом счетов.

Пример:

Процедура Сформировать()

   Сч = СоздатьОбъект("Счет");

   Сч.ИспользоватьПланСчетов(ПланыСчетов.Основной);

   Сч.ВыбратьСчета();

   Пока Сч.ПолучитьСчет() = 1 Цикл

      Сообщить("Счет " + Сч.Код);

   КонецЦикла;

КонецПроцедуры

ИспользоватьПланСчетов

Установить (получить) текущий план счетов формы списка счетов.

Синтаксис:

ИспользоватьПланСчетов(<ПланСчетов>)

Англоязычный синоним:

UseChartOfAccounts

Параметры:

<ПланСчетов>

Значение типа «ПланСчетов».

Возвращаемое значение:

Значение текущего плана счетов формы до вызова метода.

Описание:

Метод ИспользоватьПланСчетов устанавливает текущий план счетов в форме списка счетов, если форма открыта для просмотра нескольких планов счетов. Если параметр не задан, то метод позволяет получить текущий план счетов.

Данный метод доступен в контексте Модуля формы списка счетов (см. «Виды программных модулей»).

Пример:

Процедура Печать()

   Сч = СоздатьОбъект("Счет");

   Сч.ИспользоватьПланСчетов(ИспользоватьПланСчетов());

КонецПроцедуры;

ИспользоватьПланСчетов

Назначить план счетов, по которому будут выдаваться итоги.

Синтаксис:

ИспользоватьПланСчетов(<ПланСчетов>)

Англоязычный синоним:

UseChartOfAccounts

Параметры:

<ПланСчетов>

Необязательный параметр. Значение типа «План Счетов». Если не задан установка не меняется.

Возвращаемое значение:

Значение данной установки до вызова метода.

Описание:

Применение данного метода имеет смысл только если используется не­сколько планов счетов.

Метод ИспользоватьПланСчетов задает план счетов для метода получе­ния итогов и ВыполнитьЗапрос для тех случаев, когда конкретный счет не указан или задается строкой символов.

Если план счетов не установлен функцией ИспользоватьПланСчетов, будет использоваться основной план счетов, заданный в метаданных.

Пример:

БухИтоги.ИспользоватьПланСчетов(ПланыСчетов.Рабочий);

ИспользоватьРазделительУчета

Установить значение разделителя учета.

Синтаксис:

ИспользоватьРазделительУчета(<РазделительУчета>)

Англоязычный синоним:

UseAccountingDivision

Параметры:

<РазделительУчета>

Необязательный параметр. Значение разделителя учета. Если не задан, то установка не меняется.

Возвращаемое значение:

Значение данной установки до вызова метода.

Описание:

Метод ИспользоватьРазделительУчета задает значения разделителя учета для методов получения итогов и ВыполнитьЗапрос.

Применение данного метода имеет смысл только если используется разделителель учета.

Пример:

БухИтоги.ИспользоватьРазделительУчета(Константа.ОснФирма);

ИспользоватьРодителя

Установить выборку по группе справочника.

Синтаксис:

ИспользоватьРодителя(<Группа>)

Англоязычный синоним:

UseParent

Параметры:

<Группа>

Необязательный параметр. Выражение со значе­нием группы справочника.

Возвращаемое значение:

Значение текущей группы для справочника (на момент до исполнения ме­тода).

Описание:

Метод ИспользоватьРодителя устанавливает группу текущего справоч­ника в качестве параметра выборки.

Данный метод используется до вызова метода ВыбратьЭлементы, который фактически открывает выборку. Дальнейшая выборка при помощи метода ПолучитьЭлемент будет происходить только среди элементов текущего спра­вочника, принадлежащих указанной группе.

При добавлении нового элемента текущего справочника данная установка также будет являться свойством нового элемента.

Данный метод может использоваться только для объектов, созданных функцией СоздатьОбъект.

Пример:

// Это процедура формирования отчета - "Список сотрудников"

// ВыбСотр - реквизит диалога типа «справочник.Сотрудники»

Процедура ВыводСпискаСотрудников()

   Таб = СоздатьОбъект("Таблица");

   Спр = СоздатьОбъект("Справочник.Сотрудники");

   Спр.ИспользоватьДату(ДатаОтчета);

   Если ВыбСотр.Выбран() = 0 Тогда

      // если сотрудник в диалоге не выбран,

      // то формируем отчет без условий

      Заг = "По всем сотрудникам";

   ИначеЕсли ВыбСотр.ЭтоГруппа() = 1 Тогда

      // если в диалоге выбрана группа сотрудников, то

      // задаем выборку элементов справочника из одной группы

      Спр.ИспользоватьРодителя(ВыбСотр);

      // Задаем выборку всех подчиненных элементов справочника

      Заг = "По сотрудникам группы " + ВыбСотр.Наименование;

   Иначе

      // если в диалоге выбран сотрудник, то

      // формируем отчет только по нему

      Спр.НайтиЭлемент(ВыбСотр);

      Заг = "По сотруднику " + ВыбСотр.Наименование;

      Таб.ВывестиСекцию("Отчет");

      Таб.ВывестиСекцию("Сотрудник");

      Перейти ~MET;

   КонецЕсли;

   ЧислоСтрок = 0;

   Таб.ВывестиСекцию("Отчет");

   // Открываем выборку Спр.ВыбратьЭлементы();

   Пока Спр.ПолучитьЭлемент() > 0 Цикл

      ЧислоСтрок = ЧислоСтрок + 1;

      Если Спр.ЭтоГруппа() = 1 Тогда

         Таб.ВывестиСекцию("Группа");

      Иначе

         Таб.ВывестиСекцию("Сотрудник");

      КонецЕсли;

      Состояние("В отчет выведено "+ЧислоСтрок+" строк.");

   КонецЦикла;

~MET:

   //Вызов выходного отчета в окно просмотра и редактирования.

   Таб.ТолькоПросмотр(1);

   Таб.Опции(0, 0, 4, 0);

   Таб.Показать("Список товаров по каталогу", "");

   ВыбТовар = 0;

КонецПроцедуры

См. также: ВыбратьЭлементы, ПолучитьЭлемент, СоздатьОбъект

ИспользоватьРодителя

Установить родителя для формы списка справочника.

Синтаксис:

ИспользоватьРодителя(<Родитель>, <ФлагИзменения>)

Англоязычный синоним:

UseParent

Параметры:

<Родитель>	Необязательный параметр. Выражение со значением группы справочника- нового родителя. Если пара­метр не задан, то значение родителя не меняется.
<ФлагИзменения >	Необязательный параметр. Этим флагом регулирует­ся возможность интерактивного изменения родителя. 1 — пользователь может изменить родителя интерак­тивно, 0 — пользователь не может интерактивно изме­нить родителя. Если параметр не задан, то значение флага не меняется.

Возвращаемое значение:

Значение родителя для формы списка справочника (до применения метода).

Описание:

Метод ИспользоватьРодителя устанавливает группу справочника в каче­стве родителя для формы списка справочника.

Данный метод доступен в контексте Модуля формы списка справочника (см. «Виды программных модулей»). Действие данного метода относится ко всему текущему справочнику, который доступен в локальном контексте Моду­ля формы списка справочника.

При добавлении нового элемента текущего справочника данный параметр также будет являться свойством нового элемента.

Пример:

ИспользоватьРодителя(ВыбГруппаСотр, 1);

ИспользоватьРодителя

Устанавливает/выдает значение родителя (счета вышестоящего уровня), используемого для выборки счетов.

Синтаксис:

ИспользоватьРодителя(<Родитель>, <ФлагИзменения>)

Англоязычный синоним:

UseParent

Параметры:

<Родитель>	Значение типа «Счет», устанавливаемое в качестве используемого родителя. Необязательный параметр. Если параметр не указан — значение используемого родителя не изменяется.
<ФлагИзменения>	Необязательный параметр. Этим флагом регулирует­ся возможность интерактивного изменения родителя. 1 — пользователь может изменить родителя интерак­тивно, 0 — пользователь не может интерактивно изме­нить родителя.

Возвращаемое значение:

Значение типа «Счет». Текущее значение используемого родителя на мо­мент до исполнения метода.

Описание:

При наличии в плане счетов нескольких уровней счетов-субсчетов при пе­реборе или выборе счета существует возможность отбирать только счета подчи­ненные некоторому счету. Метод ИспользоватьРодителя устанавливает зна­чение, которе будет затем использовано методами перебора и выбора счета.

Пример:

Процедура Сформировать ()

   Сч = СоздатьОбъект("Счет.Основной");

   Сч.ИспользоватьРодителя(СчетПоКоду("01"));

   Сч.ВыбратьСчета();

   Пока Сч.ПолучитьСчет(0) = 1 Цикл

      Сообщить(Сч.Код);

   КонецЦикла;

КонецПроцедуры

ИспользоватьРодителя

Установить родителя для формы списка счетов.

Синтаксис:

ИспользоватьРодителя(<Родитель>, <ФлагИзменения>)

Англоязычный синоним:

UseParent

Параметры:

<Родитель>	Выражение со значением счета.
<ФлагИзменения>	Необязательный параметр. Этим флагом регулирует­ся возможность интерактивного изменения родителя. 1 — пользователь может изменить родителя интерак­тивно, 0 — пользователь не может интерактивно изме­нить родителя.

Возвращаемое значение:

Значение родителя для формы списка счетов (до применения метода).

Описание:

Метод ИспользоватьРодителя устанавливает счет в качестве основного для формы списка счетов (показываются субсчета выбранного счета).

Данный метод доступен в контексте Модуля формы списка счетов (см. «Виды программных модулей»). Действие данного метода относится ко всему текущему списку счетов, который доступен в локальном контексте Модуля формы списка счетов.

При добавлении нового субсчета текущего плана счетов данный параметр также будет являться свойством нового субсчета.

Пример:

ИспользоватьРодителя(ВыбСчет, 1);

ИспользоватьСлой

Установить режим отображения слоя в форме.

Синтаксис:

ИспользоватьСлой(<ИмяСлоя>, <Режим>)

Англоязычный синоним:

UseLayer

Параметры:

<ИмяСлоя>	Строковое выражение — название слоя формы как оно задано в конфигураторе. Параметр может быть составным (указывать несколько слоев). В этом случае имена слоев перечисляются через запятую.
<Режим>	Необязательный параметр. Числовое выражение: 0 — скрыть слой <ИмяСлоя> в форме; 1 — показать слой <ИмяСлоя> в форме; 2 — показать слой <ИмяСлоя> и скрыть все ос­тальные. Значение по умолчанию — 2.

Описание:

Метод Использовать Слой устанавливает режим отображения слоя в фор­ме. Доступ к данному методу возможен только в контексте Модуля формы.

Пример:

Форма.ИспользоватьСлой("Основной, КнопкиДиалога, Дополнительный", 1);

См. также: Закладки, ПриВыбореЗакладки

ИспользоватьСписокЭлементов

Реализует фильтрацию элементов справочника используя нединами­ческий фильтр.

Синтаксис:

ИспользоватьСписокЭлементов (<СписокЗначений>)

Англоязычный синоним:

UseItemList

Параметры:

<СписокЗначений>

Необязательный параметр. Значение типа «СписокЗначений». Должен представлять собой список элементов справочника, выбранных для просмотра. Если это значение пустое, то фильтр отключается.

Описание:

Метод ИспользоватьСписокЭлементов реализует фильтрацию элементов справочника. Устанавливает нединамический фильтр.

Рекомендуется применять в предопределенных процедурах ПриСменеРодителя, ПриОткрытии, ПриСменеИерархии. При этом формиру­ется список «разрешенных» элементов, который передается форме списка спра­вочника при помощи данного метода. Данный список должен являться под­множеством тех элементов, которые обычно отображаются в форме списка без применения фильтра.

После вызова метода ИспользоватьСписокЭлементов форма списка справочника не позволяет вводить новый элемент, копировать и т. п.

Данный метод доступен в контексте Модуля формы списка справочника (см. «Виды программных модулей»). Действие данного метода относится ко всему текущему списку справочника, который доступен в локальном контексте Модуля формы списка справочника.

Пример:

Процедура УстановитьФильтр(ВыбПризнак)

   Список.СоздатьОбъект("СписокЗначений");

   Буфер = СоздатьОбъект("Справочник.Главн");

   // отбираем только те элементы, которые могут отображаться в текущем списке

   Буфер.ИспользоватьРодителя(ИспользоватьРодителя());

   Буфер.ВключатьПодчиненные(0);

   Буфер.ВыбратьЭлементы();

   Пока Буфер.ПолучитьЭлемент() = 1 Цикл

      // отбираем только те элементы, которые удовлетворяют заданному признаку

      Если (Буфер.Признак = ВыбПризнак) Тогда

         Список.ДобавитьЗначение(Буфер.ТекущийЭлемент());

      КонецЕсли;

   КонецЦикла;

   ИспользоватьСписокЭлементов(Список);

КонецПроцедуры

ИспользоватьСубконто

Задает фильтр по субконто для функции ВыбратьОперацииСПроводками.

Синтаксис:

ИспользоватьСубконто(<ВидСубконто>, <Субконто>)

Англоязычный синоним:

UseSubconto

Параметры:

<ВидСубконто>	Значение типа «ВидСубконто» — отбор проводок будет выполнен только для субконто указанного вида.
<Субконто>	Значение субконто — отбор проводок будет вы­полнен только для указанного субконто. Кроме того, в качестве значения данного параметра можно передавать «Список значений».

Описание:

Метод ИспользоватьСубконто устанавливает фильтр по субконто, кото­рый используется при отборе проводок методом ВыбратьОперацииСПроводками.

Метод ИспользоватьСубконто может вызываться последовательно не­сколько раз. В этом случае фильтры, устанавливаемые этой функцией, сумми­руются.

Пример:

Опер = СоздатьОбъект("Операция");

Опер.ИспользоватьСубконто(ВидыСубконто.Организации, ВыбОрг);

Опер.ВыбратьОперацииСПроводками(ДатаНач, ДатаКон, "60");

Пока Опер.ПолучитьПроводку() = 1 Цикл

   Сообщить("Сумма " + Опер.Сумма);

КонецЦикла;

ИспользоватьСубконто

Установка субконто используемого по умолчанию.

Синтаксис:

ИспользоватьСубконто(<ВидСубконто>, <Субконто>)

Англоязычный синоним:

UseSubconto

Параметры:

<ВидСубконто>	Значение типа «ВидСубконто».
<Субконто>	Необязательный параметр. Значение субконто. Если параметр не задан, установка не изменяется.

Возвращаемое значение:

Значение установки используемого по умолчанию субконто на момент до вызова метода.

Описание:

Данный метод устанавливает в форме используемые по умолчанию значе­ния субконто разных видов. Они будут автоматически подставляться субконто проводок, если в проводках используются счета с этими видами субконто. По­сле автоматической подстановки пользователь может изменить субконто по своему усмотрению.

Пример:

Процедура ПриОткрытии()

   ИспользоватьСубконто(ВидыСубконто.Склады, Константа.ОснСклад);

КонецПроцедуры;

ИспользоватьСубконто

Устанавливает режим получения итогов методом ВыполнитьЗапрос в разрезе субконто.

Синтаксис:

ИспользоватьСубконто(<ВидСубконто>, <Субконто>, <ТипФильтра>, <ПоГруппам>)

Англоязычный синоним:

UseSubconto

Параметры:

<ВидСубконто>	Значение типа «Вид Субконто» — расчет времен­ных итогов будет выполнен только для субконто указанного вида. Задается значением типа «Вид Субконто» или строкой содержащей имя иденти­фикатора вида субконто, как он назван в конфи­гураторе.
<Субконто>	Необязательный параметр. Здесь может быть за­дано или одно конкретное значение субконто, по которому будут отобраны итоги по аналитике или объект типа «Список значений», где можно задать несколько значений субконто. Если параметр не задан — то считается пустым значением субконто.
<ТипФильтра>	Необязательный параметр. Число — тип фильтра по субконто. Может принимать следующие значе­ния: 1 — разворачивать по данному субконто, 2 — отбирать по данному субконто, 3 — не учитывать это субконто вообще. По умолчанию 1.
<ПоГруппам>	Необязательный параметр. Число — группировка др итогов по субконто. Параметр <ПоГруппам> имеет смысл, если параметр <ТипФильтра> равен 1, а вид субконто, заданный параметром <ВидСубконто>, имеет тип значения «Справочник». Параметр может принимать значения: 0 — не показывать итоги по группам справочника; 1 — показывать итоги по группам справочника. По умолчанию 0.

Описание:

Метод ИспользоватьСубконто устанавливает режим отбора итогов по субконто методом ВыполнитьЗапрос.

Метод ИспользоватьСубконто слудет вызывать до вызова метода ВыполнитьЗапрос. После выполнения метода ВыполнитьЗапрос установки метода ИспользоватьСубконто сбрасываются и перед слудеющим запросом их нужно устанавливать заново.

Метод ИспользоватьСубконто может вызываться последовательно не­сколько раз. В этом случае установки, выполняемые этим методом суммируют­ся.

Использование параметра <ТипФильтра> со значением 1 (разворачивать) в сочетании с выбранной группой справочника в параметре <Субконто> позво­ляет получить итоги по всем элементам данной группы.

Пример:

* Данный запрос формирует итоги по счету 10 в разрезе материалов по од­ному складу.

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Материалы, , 1);

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Склады, ВыбСклад, 2);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон, "10");

ИспользоватьВалюту

Установка валюты используемой по умолчанию.

Синтаксис:

МспользоватьВалюту(<Валюта>)

Англоязычный синоним:

UseCurrency

Параметры:

<Валюта>

Необязательный параметр. Значение типа «Спра­вочник», имеющий вид, определенный при на­стройке валютного учета. Если параметр не задан, установка не изменяется.

Возвращаемое значение:

Значение установки используемой валюты на момент до вызова метода.

Описание:

Данный метод устанавливает в форме используемую по умолчанию валюту. Она будет автоматически подставляться в валюту вводимых проводок, если в проводках используются валютные счета. После автоматической подстановки пользователь может изменить валюту по своему усмотрению.

Пример:

Процедура ПриОткрытии()

   ИспользоватьВалюту(Константа.ОснВалюта);

КонецПроцедуры;

ИспользоватьВладельца

Установить выборку подчиненного справочника.

Синтаксис:

ИспользоватьВладельца(<Владелец>, <ФлагИзменения>)

Англоязычный синоним:

UseOwner

Параметры:

<Владелец>	Необязательный параметр. Выражение со значением элемента справочника-владельца.
<ФлагИзменения>	Необязательный параметр. Этим флагом регулирует­ся возможность интерактивного изменения владель­ца. 1 — пользователь может изменить владельца интерактивно, 0 — пользователь не может интерактивно изменить владельца. Этот параметр используется в случае использовсния данного метода для объектов типа «справочник», которые являются реквизитами формы или реквизитами диалога.

Возвращаемое значение:

Значение элемента справочника-владельца для текущего подчиненного справочника (на момент до исполнения метода).

Описание:

Метод ИспользоватьВладельца может применяться к объектам типа «справочник» в двух случаях:

Для объектов, созданных функцией СоздатьОбъект, метод ИспользоватьВладельца устанавливает элемент справочника-владельца (которому подчинен текущий подчиненный справочник) в ка­честве параметра выборки. Данный метод используется до вызова метода ВыбратьЭлементы, который фактически открывает выборку. Дальней­шая выборка при помощи метода ПолучитьЭлемент будет происходить только среди тех элементов текущего подчиненного справочника, для которых владельцем является заданное значение элемента справочника-владельца <Владелец>. При записи нового элемента текущего справоч­ника данный метод также задает владельца для нового элемента.

Для объектов типа «справочник», которые являются реквизитами фор­мы (например, в форме документа — реквизит документа типа «спра­вочник») или реквизитами диалога (например, в форме отчета — рекви­зит диалога типа «справочник») метод ИспользоватьВладельца по­зволяет программно установить некоторое значение справочника-владельца в качестве владельца, который будет использован при инте­рактивном выборе значения данного реквизита.

Пример:

// Процедура выводит список детей сотрудника

// Справочник детей подчинен справочнику сотрудников

Процедура ВыводСпискаДетей(Сотр)

   СпрД = СоздатьОбъект("Справочник.Дети");

      // в качестве параметра функции ИспользоватьВладельца

      // передаем параметр, переданный в процедуру

   СпрД.ИспользоватьВладельца(Сотр);

   Сообщить("Дети сотрудника " + Сотр.Наименование);

   СпрД.ВыбратьЭлементы();

   Пока СпрД.ПолучитьЭлемент() > 0 Цикл

      Сообщить(СпрД.Наименование);

   КонецЦикла;

КонецПроцедуры

Пример:

// В форме элемента справочника Товары есть реквизит Единица,

// который имеет тип подчиненного справочника «Единицы»

// здесь мы можем задать ему в качестве владельца текущий элемент:

Единица.ИспользоватьВладельца(ТекущийЭлемент());

См. также: ВыбратьЭлементы, ПолучитьЭлемент, СоздатьОбъект

ИспользоватьВладельца

Установить владельца для формы списка подчиненного справочника.

Синтаксис:

ИспользоватьВладельца(<Владелец>, <ФлагИзменения>)

Англоязычный синоним:

UseOwner

Параметры:

<Владелец>	Необязательный параметр. Выражение со значением элемента справочника — нового владельца. Если па­раметр не задан, то значение владельца не меняется.
<ФлагИзменения>	Необязательный параметр. Этим флагом регулирует­ся возможность интерактивного изменения владель­ца, 1 — пользователь может изменить владельца инте­рактивно, 0 — пользователь не может интерактивно изменить владельца. Если параметр не задан, то зна­чение флага не меняется.

Возвращаемое значение:

Значение владельца для формы списка подчиненного справочника (до при­менения метода).

Описание:

Метод ИспользоватьВладельца устанавливает элемент связанного спра­вочника (которому подчинен текущий справочник) в качестве владельца для формы списка подчиненного справочника.

Данный метод доступен в контексте Модуля формы списка справочника (см. «Виды программных модулей»). Действие данного метода относится ко всему текущему подчиненному справочнику, который доступен в локальном контексте Модуля формы списка справочника.

При добавлении нового элемента текущего справочника данный параметр также будет являться свойством нового элемента.

Пример:

ИспользоватьВладельца(Сотр, 0);

ИспользоватьЗакладки

Установить режим использования закладок в форме.

Синтаксис:

ИспользоватьЗакладки(<Флаг>)

Англоязычный синоним:

TabCtrlState

Параметры:

<Флаг>

Необязательный параметр. Числовое выражение: 1 — включить закладки в форме; 0 — выключить закладки в форме.

Возвращаемое значение:

Текущее значение режима использования закладок формы (на момент до исполнения метода).

Описание:

Метод ИспользоватьЗакладки устанавливает режим использования за­кладок в форме.

Доступ к данному методу возможен только в контексте Модуля формы.

Пример:

Форма.ИспользоватьЗакладки(1)

См. также: Закладки, ПриВыбореЗакладки, ИспользоватьСлой

ИспользоватьЖурнал

Использовать журнал для отбора документов и доступа к графам.

Синтаксис:

ИспользоватьЖурнал(<Журнал>, <ФлагОгрПросм>)

Англоязычный синоним:

UseJournal

Параметры:

<Журнал>	Идентификатор журнала, который предполагается использовать для отбора документов и доступа к графам.
<ФлагОгрПросм>	Необязательный параметр. Число: 1 — если выборка ограничивается документами, входящими в указан­ный журнал; 0 — если метод используется только для использования граф методом Графа. Значение по умолчанию 1.

Описание:

Метод ИспользоватьЖурнал позволяет при переборе документов коман­дой Выбрать использовать журнал для отбора документов и доступа к графам журнала.

Пример:

Док = СоздатьОбъект("Документ.НаклПрих");

Док.ИспользоватьЖурнал("Приходные");

См. также: Графа

Исправить

Исправление результата записи журнала расчетов.

Синтаксис:

Исправить(<НовыйРезультат>)

Англоязычный синоним:

Update

Параметры:

<НовыйРезультат>

Новый результат записи журнала расчетов.

Описание:

Метод выполняет то же действие, что и интерактивная процедура исправле­ния результата, т. е. при исправлении записи текущего расчетного периода про­сто редактируется результат и метится запись «ручкой», а при исправлении записи прошлого периода — вводится сторно той записи и еще одна запись-исправление. Описание интерактивной процедуры исправления результата можно посмотреть в книге «Руководство пользователя».

Исправлена

Признак того, что запись исправлена вручную.

Синтаксис:

Исправлена

Англоязычный синоним:

Updated

Описание:

Атрибут типа «число», принимает два значения: 1 — для записей журнала расчетов, результат которых исправлен «вручную» и 0 — для остальных запи­сей.

Запись журнала расчетов становится исправленной при редактировании ре­зультата расчета непосредственно в журнале расчетов. Исправленные вручную записи не редактируются при очередном сеансе расчета, т. е. результат автома­тического расчета не заменяет результат ручного ввода. Это значит, что резуль­тат ручного редактирования «главнее» результата автоматического расчета.

Атрибут Исправлена предназначен только для чтения.

Пример:

// Проверим, не редактировали ли результаты ЖрнЗарплата = СоздатьОбъект("ЖурналРасчетов.Зарплата");

ЖрнЗарплата.ВыбратьЗаписиПоДокументу(ТекущийДокумент());

Счетчик = 0;

Пока ЖрнЗарплата.ПолучитьЗапись() = 1 Цикл

   Если ЖрнЗарплата.Исправлена = 1 Тогда

      Счетчик = Счетчик + 1;

   КонецЕсли;

КонецЦикла;

Если Счетчик <> 0 Тогда

   Сообщение("Исправленных записей — " + Счетчик);

КонецЕсли;

// продолжим формирование документа

См. также: Рассчитана, Фиксирована

Строковое выражение, содержащее имя реквизита

Итоговое значение реквизита документа.
Синтаксис:
Итог(<ИмяРеквизита>)
Англоязычный синоним:
Total
Параметры:

<ИмяРеквизита>

Строковое выражение, содержащее имя реквизита табличной части документа, для которого в кон­фигураторе установлено свойство «Итог по ко­лонке».

Возвращаемое значение:
Числовое значение — сумма по всем строкам табличной части документа для реквизита <ИмяРеквизита>.
Описание:
Метод Итог позволяет определить сумму значений по всем строкам таб­личной части документа для реквизита <ИмяРеквизита>.
Данный метод может быть использован только для реквизитов табличной части документов, для которых установлено свойство «Итог по колонке» (за­кладка «Дополнительные» свойств реквизита документа в конфигураторе).
Пример:
Процедура ВычСреднего()
   // вычислим среднюю сумму по наряду
   Сумма = Итог("Сумма");
   Штук = Итог("Штук");
   Если Штук <> 0 Тогда
      Средн = Сумма / Штук;
   Иначе;
      Средн = 0;
   КонецЕсли;
КонецПроцедуры


Возвратить итог одного ресурса оборотного регистра.
Синтаксис:
Итог(<Измерен1>, <Измерен2>..., <ИмяРесурса>)
Англоязычный синоним:
Total
Параметры:

<Измерен1>, <Измерен2>...	Выражения со значениями измерений регистра.
<ИмяРесурса>	Строковое выражение, содержащее на­звание требуемого ресурса регистра, как оно названо в конфигураторе.

Возвращаемое значение:
Численое значение итога заданного ресурса регистра.
Описание:
Метод Итог возвращает итог по ранее установленному периоду ресурса <ИмяРесурса> оборотного регистра.
Данный метод используется только для оборотных регистров.
Пример:
Функция ПолучитьИтог(Товар, Склад, Год);
   Регистр.ОборотыТоваров.ИспользоватьПериод(Год);
   Возврат Регистр.ОборотыТоваров.Итог(Товар, Склад, "ОборотТовара");
КонецФункции


Вычислить сумму по колонке таблицы значений.
Синтаксис:
Итог(<Колонка>)
Англоязычный синоним:
Total
Параметры:

<Колонка>

Номер или идентификатор колонки, по которой считать сумму.

Возвращаемое значение:
Сумма по колонке.
Описание:
Метод Итог вычисляет сумму по заданной колонке таблицы значений.
Пример:
Табл.Итог(2);

Извлечь все итоги ресурсов оборотного

Извлечь все итоги ресурсов оборотного регистра.
Синтаксис:
Итоги(<Измерен1>, <Измерен2>...)
Англоязычный синоним:
Totals
Параметры:

<Измерен1>, <Измерен2>...

Выражения со значениями измерений регистра.

Описание:
Метод Итоги извлекает итоги по всем ресурсам по ранее установленному периоду оборотного регистра. Полученные итоги ресурсов затем можно считы­вать из атрибутов регистра.
Данный метод используется только для оборотного регистра.
Пример:
Регистр.ОборотыТоваров.ИспользоватьПериод(Год);
Регистр.ОборотыТоваров.Итоги(Товар, Склад);
ОбТов = Регистр.ОборотыТоваров.ОборотТовара;

ИтогиАктуальны

Возвратить флаг актуальности итогов.

Синтаксис:

ИтогиАктуальны()

Англоязычный синоним:

AreTotalsActual

Возвращаемое значение:

Числовое значение: 1 — итоги актуальны, 0 — нет.

Описание:

Метод ИтогиАктуальны позволяет определить — выполняется ли проведе­ние документа в реальном времени или задним числом (когда нельзя обращать­ся к текущим остаткам регистров).

Данный метод доступен только в контексте Модуля документа в предопре­деленной процедуре ОбработкаПроведения (см. Гл. «Системные предопре­деленные процедуры»).

Пример:

Процедура ОбработкаПроведения()

   // Для расходной накладной ВыбратьСтроки();

   Пока ПолучитьСтроку() > 0 Цикл

      Если ИтогиАктуальны() > 0 Тогда

         // если итоги актуальны,

         // то текущие стоимости берем из текущих остатков

         Регистр.ОстаткиТоваров.Склад = Скпад;

         Регистр.ОстаткиТоваров.Товар = Товар;

         Регистр.ОстаткиТоваров.ОстаткиПолучить();

         Регистр.ОстаткиТоваров.БазоваяСтоимость =

                 Регистр.ОстаткиТоваров.БазоваяСтоимость * Количество *

                 Коэффициент / Регистр.ОстаткиТоваров.ОстатокТовара;

         Регистр.ОстаткиТоваров.ВалютнаяСтоимость =

                 Регистр.ОстаткиТоваров.ВалютнаяСтоимость * Количество *

                 Коэффициент / Регистр.ОстаткиТоваров.ОстатокТовара;

         Регистр.ОстаткиТоваров.ОстатокТовара = Количество * Коэффициент;

         Регистр.ОстаткиТоваров.ДвижениеРасходВыполнить();

      Иначе

         // если итоги не актуальны,

         //то стоимости берем из врем. расчета Регистра

         Рег = СоздатьОбъект("Регистр.ОстаткиТоваров");

         Рег.ВременныйРасчет();

         РассчитатьРегистрыНа(ТекущийДокумент());

         Рег.Товар = Товар;

         Рег.Склад = Склад;

         Рег.ОстаткиПолучить();

         Регистр.ОстаткиТоваров.БазоваяСтоимость =

                 Рег.БазоваяСтоимость * Количество * Коэффициент /

                 Рег.ОстатокТовара;

         Регистр.ОстаткиТоваров.ВалютнаяСтоимость =

                 Рег.ВалютнаяСтоимость * Количество * Коэффициент /

                 Рег.ОстатокТовара;

         Регистр.ОстаткиТоваров.ОстатокТовара = Количество * Коэффициент;

         Регистр.ОстаткиТоваров.Склад = Склад;

         Регистр.ОстаткиТоваров.Товар = Товар;

         Регистр.ОстаткиТоваров.ДвижениеРасходВыполнить();

      КонецЕсли;

   КонецЦикла;

КонецПроцедуры

ИтогиПолучить

Получить все ресурсы по регистру.

Синтаксис:

ИтогиПолучить()

Англоязычный синоним:

TotalsGet

Описание:

Метод ИтогиПолучить извлекает все итоги ресурсов оборотного регистра по измерениям, содержащимся в атрибутах. Полученные ресурсы затем можно считывать из атрибутов регистра.

Данный метод используется только для оборотного регистра.

Пример:

Регистр.ОборотыТоваров.Товар = Конт.Товар;

Регистр.ОборотыТоваров.Склад = Конт.Склад;

Регистр.ОборотыТоваров.ИтогиПолучить();

Сообщить("Оборот товара=" + Регистр.ОборотыТоваров.ОборотТовара;

ИзменениеПорядкаСтрок

Установить режим изменения порядка строк в форме документа.

Синтаксис:

ИзменениеПорядкаСтрок(<Разрешить>)

Англоязычный синоним:

ChangeLinesOrder

Параметры:

<Разрешить>

Необязательный параметр. Число: 1 — разрешить изменение порядка строк в документе; 0 — запре­тить. Если параметр не задан, то режим не меня­ется.

Возвращаемое значение:

Режим изменения порядка строк до исполнения метода. Число: 1 — разре­шено изменение порядка строк в документе; 0 — запрещено.

Описание:

Метод ИзменениеПорядкаСтрок позволяет установить режим изменения порядка строк в форме документа.

Данный метод доступен только в контексте Модуле формы документа (см. «Виды программных модулей»). Действие данного метода относится только к текущему документу, который доступен в локальном контексте Модуля формы документа.

Пример:

ИзменениеПорядкаСтрок(0);

---

---